Пятница, 29.03.2024, 21:13
Вы вошли как Гость | Группа "Гости" | RSS

.
 
 
Главная Регистрация Вход
[ Новые сообщения · Участники · Правила форума · Поиск · RSS ]
  • Страница 1 из 1
  • 1
Модератор форума: Nemesis_c  
Форум » Elektropage.ru » Other » Contra Hard Corps - мозгохак
Contra Hard Corps - мозгохак
Nemesis_cДата: Вторник, 27.09.2011, 14:47 | Сообщение # 1


 
Сообщений: 1148
Статус: Offline
 

чтоб инфу не потерять - собрал все в кучу в один фаилик и родилось оно... smile

Оно умеет:
- возвращать хитпоинты из J версии
- возвращать читкоды из J dthcbb
- придумывать свои читы
- менять звуки на читах
- менять таилы хитпоинтов
- увеличивать/уменьшать лимит жизней
- менять джойстики для ввода паролей
- делать возможным выбор одинаковых бойцов

подходит как для оригинала U так и для хака от миджет.

Оно:
Code

      ;Nemesis_c 2011.09.27      
      ;Thanks to r57shell & Apocalipsis
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      org $0
      incbin Contra.bin
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;CHANGING RESET OF HITPOINTS TO SUBTRACT
      org $11d40
      sub.b   d1,$D(a2)
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      org $1ff000 ; set to empty space to add new code
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;NEW CODE:
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;DRAW HITPOINTS
      hitpoints_draw:
      loc_0:                        
      tst.w   d0
      ble.s   loc_1
      move.w  #$800D,-4(a5) ; 800D is a tile № of full hitpoint      
      subq.w  #1,d0
      subq.w  #1,d1
      bra.s   loc_3
      loc_1:                        
      tst.w   d1
      ble.s   loc_2
      move.w  #$800E,-4(a5) ; 800E is a tile № of empty hitpoint
      subq.w  #1,d1
      bra.s   loc_3
      loc_2:                        
      move.w  #$8006,-4(a5)
      loc_3:                        
      dbf     d2,loc_0
      jmp     $1F0D8
      org $1fffe0
      hitpoints_draw2:
      move.b  (a6)+,d0
      move.b  d0,d1
      andi.w  #$F,d0
      andi.w  #$F0,d1
      asr.w   #4,d1
      moveq   #3,d2
      move.w  #$8F02,(a5)
      move.l  d7,(a5)
      jmp     $1F0CC
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; ADD ALL WEAPON CHEAT CODE
      enable_cheats:
      jsr $0000D344
      jsr $0000551A
      rts
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; ADD 70 LIVES & STAGE SELECTION CHEAT CODE
      lives_and_stage:
      jsr     $00059790
      move.w  #$328,(a6)
      jsr     $00059790
      move.w  #$32B,(a6)
      jsr     $00059790
      move.w  #$32C,(a6)
      jsr     $00059790
      move.w  #$3F8,(a6)
      jmp     $0000C126
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; ADD NEW CHEAT CODE (<><>ABCBA^V on title screen = debud level)
      new_cheatcode:
      tst.w   2(a1)
      bne.s   loc_1A
      move.b  #2,$1C(a1)
      move.l  #new_code,$78(a1)
      addq.w  #1,2(a1)
      rts
      loc_1A:                        
      move.b  ($FFFFA062).w,d7
      beq.s   loc_4C
      movea.l $78(a1),a0
      cmp.b   (a0),d7
      bne.s   loc_48
      addq.l  #1,$78(a1)
      movea.l $78(a1),a0
      tst.b   (a0)
      bne.s   loc_4C
      move.w  #$22,d0 ; ($22) is a number of a sound after <><>ABCBA^V code entered =)
      jsr     $A8042
      move.w  #1,($FFFFFA48).w
      clr.w   (a1)
      rts
      loc_48:                        
      clr.w   2(a1)
      loc_4C:                     
      jmp     $5B790
      nop
      new_code:
      dc.l $04080408
      dc.l $40102010
      dc.l $40010200
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;END OF NEW CODE
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;FIX LINK FOR ALL WEAPON CHEAT CODE
      org $520
      jsr enable_cheats
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; FIX LINKS FOR 70 LIVES & STAGE SELECTION CHEAT CODES
      org $c11c
      jmp lives_and_stage
      nop
      nop
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; ESTABLISH FIRST CONTROLLER TO ENTER CHEAT CODES      
      org $5b6e9
      dc.b $62
      org $5b747
      dc.b $62
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;CHANGE LINK FOR NEW CHEAT CODE
      org $5b788
      jmp new_cheatcode
      nop
      rts
      dc.l $4e714e71, $4e714e71, $4e714e71, $4e714e71, $4e714e71
      dc.l $4e714e71, $4e714e71, $4e714e71, $4e714e71, $4e714e71
      dc.l $4e714e71, $4e714e71, $4e714e71, $4e714e71, $4e714e71
      dc.l $4e714e71, $4e714e71, $4e714e71, $4e714e71, $4e714e71
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;CHANGE LINKS FOR HITPOINTS DRAW
      org $1f0c4
      jmp hitpoints_draw2
      nop
      nop
      jmp hitpoints_draw
      nop
      nop
      rts
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; CHANGE MAXIMUM OF LIVES IN MAIN MENU
      org $96e3
      dc.b $0a ; 10 lives
      org $96f5
      dc.b $0a
      org $96ff
      dc.b $0a
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ;ADD POSSIBILITY TO CHOOSE SAME CHARACTER (press "down" button)
      org $91da
      nop
      nop
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      org $38a
      nop
      org $394
      nop
      org $39c
      nop
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      ; SOUNDS OF CHEAT CODES
      org $5b702
      dc.w $0023 ; ($1e) is a number of sound after <>ABC<>ABC<>ABC code entered
      org $5b760
      dc.w $001d ; ($1d) is a number of sound after CBA><CBA><CBA>< code entered      
      org $d39e
      dc.w $0022; ($1c) is a number of sound after ^^VVA^^VVB^^VVC code entered
      ;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
      
Прикрепления: contra_dis.rar (74.9 Kb)
 
Форум » Elektropage.ru » Other » Contra Hard Corps - мозгохак
  • Страница 1 из 1
  • 1
Поиск:


Select language:
English
French
German
Portuguese
Chinese
Nemesis_c, r57shell, Smoke, Lipetsk, GoodBye (aka vfiuchcikicshuusrch) & Segaman © 2024
Хостинг от uCoz